跳至主要內容

工具代码

chanchaw大约 5 分钟hardware

CRC

在 vb6.0 中创建类，黏贴下面代码，调用函数 GetCRCString 传入被计算的字符串，返回计算后的CRC校验码

Option Explicit

'VB6实现CRC的工具类
'字节值表的方法

Private Function GetCRCHi(Ind As Long) As Byte
    GetCRCHi = Choose(Ind + 1, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, _
    &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, _
    &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, _
    &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, _
    &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, _
    &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, _
    &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, _
    &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, _
    &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, _
    &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, _
    &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, _
    &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, _
    &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, _
    &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, _
    &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, _
    &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, _
    &H41, &H0, &HC1, &H81, &H40)
End Function

Private Function GetCRCLo(Ind As Long) As Byte
    GetCRCLo = Choose(Ind + 1, &H0, &HC0, &HC1, &H1, &HC3, &H3, &H2, &HC2, &HC6, &H6, &H7, &HC7, _
    &H5, &HC5, &HC4, &H4, &HCC, &HC, &HD, &HCD, &HF, &HCF, &HCE, &HE, &HA, &HCA, &HCB, &HB, &HC9, _
    &H9, &H8, &HC8, &HD8, &H18, &H19, &HD9, &H1B, &HDB, &HDA, &H1A, &H1E, &HDE, &HDF, &H1F, &HDD, _
    &H1D, &H1C, &HDC, &H14, &HD4, &HD5, &H15, &HD7, &H17, &H16, &HD6, &HD2, &H12, &H13, &HD3, &H11, _
    &HD1, &HD0, &H10, &HF0, &H30, &H31, &HF1, &H33, &HF3, &HF2, &H32, &H36, &HF6, &HF7, &H37, &HF5, _
    &H35, &H34, &HF4, &H3C, &HFC, &HFD, &H3D, &HFF, &H3F, &H3E, &HFE, &HFA, &H3A, &H3B, &HFB, &H39, _
    &HF9, &HF8, &H38, &H28, &HE8, &HE9, &H29, &HEB, &H2B, &H2A, &HEA, &HEE, &H2E, &H2F, &HEF, &H2D, _
    &HED, &HEC, &H2C, &HE4, &H24, &H25, &HE5, &H27, &HE7, &HE6, &H26, &H22, &HE2, &HE3, &H23, &HE1, _
    &H21, &H20, &HE0, &HA0, &H60, &H61, &HA1, &H63, &HA3, &HA2, &H62, &H66, &HA6, &HA7, &H67, &HA5, _
    &H65, &H64, &HA4, &H6C, &HAC, &HAD, &H6D, &HAF, &H6F, &H6E, &HAE, &HAA, &H6A, &H6B, &HAB, &H69, _
    &HA9, &HA8, &H68, &H78, &HB8, &HB9, &H79, &HBB, &H7B, &H7A, &HBA, &HBE, &H7E, &H7F, &HBF, &H7D, _
    &HBD, &HBC, &H7C, &HB4, &H74, &H75, &HB5, &H77, &HB7, &HB6, &H76, &H72, &HB2, &HB3, &H73, &HB1, _
    &H71, &H70, &HB0, &H50, &H90, &H91, &H51, &H93, &H53, &H52, &H92, &H96, &H56, &H57, &H97, &H55, _
    &H95, &H94, &H54, &H9C, &H5C, &H5D, &H9D, &H5F, &H9F, &H9E, &H5E, &H5A, &H9A, &H9B, &H5B, &H99, _
    &H59, &H58, &H98, &H88, &H48, &H49, &H89, &H4B, &H8B, &H8A, &H4A, &H4E, &H8E, &H8F, &H4F, &H8D, _
    &H4D, &H4C, &H8C, &H44, &H84, &H85, &H45, &H87, &H47, &H46, &H86, &H82, &H42, &H43, &H83, &H41, _
    &H81, &H80, &H40)
End Function

'将使用字符串表示的数值转换为字节数组
Private Function String2ByteArray(ByVal vData As String) As Byte()
    Dim byteInstruction() As Byte
    Dim i As Long
    If Len(vData) Mod 2 = 0 And Len(vData) <> 0 Then '检验16进制字符串长
        ReDim byteInstruction(Len(vData) / 2 - 1)
        For i = 0 To Len(vData) - 1 Step 2
           byteInstruction(i / 2) = Val("&H" & Mid(vData, i + 1, 2))
        Next
    End If

    String2ByteArray = byteInstruction
End Function


'传入字符串
'返回CRC的校验码
'返回值是用字符串表示的16进制
Public Function GetCRCString(ByVal vData As String) As String
    Dim arrByteInstruction() As Byte
    arrByteInstruction = String2ByteArray(vData)

    Dim lCRC As Long
    lCRC = GetCRCLong(arrByteInstruction)

    Dim szCRC As String
    szCRC = Hex(lCRC)

    'CRC-16得到的校验码字符串长度应该是4
    '检测缺少几个字符就在前面补足几个0
    Dim diffLength As Integer
    diffLength = 4 - Len(szCRC)
    Dim i As Integer
    For i = 1 To diffLength
        szCRC = "0" & szCRC
    Next i

    GetCRCString = szCRC
End Function

'传入：字节数组
'返回：CRC校验码的整数类型
'将返回的整数类型通过Hex(整数类型校验码)转换为16进制的字符串
Private Function GetCRCLong(data() As Byte) As Long

    Dim CRC16Hi As Byte
    Dim CRC16Lo As Byte

    CRC16Hi = &HFF
    CRC16Lo = &HFF

    Dim i As Integer
    Dim iIndex As Long

    For i = 0 To UBound(data)

    iIndex = CRC16Hi Xor data(i)

    CRC16Hi = CRC16Lo Xor GetCRCHi(iIndex) '低位处理

    CRC16Lo = GetCRCLo(iIndex) '高位处理

    Next i

    Dim ReturnData(1) As Byte
    Dim test As Long

    ReturnData(0) = CRC16Hi 'CRC低位

    ReturnData(1) = CRC16Lo 'CRC高位

    test = Val(Str(ReturnData(0))) * 256 + Val(Str(ReturnData(1)))

    GetCRCLong = test

End Function

进制转换

' 十进制转十六进制，不足两位时补充为两个长度的字符串
Private Function DecimalToHex2Len(decimalStr As String) As String
    Dim str As String
    str = DecimalToHex(decimalStr)
    If Len(str) = 1 Then
        DecimalToHex2Len = "0" & str
    Else
        DecimalToHex2Len = str
    End If
End Function

' 将十进制字符串转换为十六进制
Private Function DecimalToHex(decimalStr As String) As String
    On Error Resume Next
    Dim num As Variant
    
    ' 尝试转换为数值
    If InStr(decimalStr, ".") > 0 Then
        num = CDbl(decimalStr)
    Else
        num = CLng(decimalStr)
    End If
    
    If Err.Number = 0 Then
        DecimalToHex = Hex(num)
    Else
    	DecimalToHex = "转换十进制为十六进制时出现异常，非法的数字"
    End If
    On Error GoTo 0
End Function

反转（小端序）

接收到的响应数据默认是大端序，即从响应数据中截取数据段时直接 IEEE754 就可得到正确结果的是大端序，如果设备要求按照小端序解码，则使用下面函数先反转再解码，会将原本的 C2ED4000 反转为 0040EDC2

Private Function ReverseHexEndian(ByVal hexStr As String) As String
    Dim i As Integer
    Dim result As String
    result = ""
    
    For i = Len(hexStr) - 1 To 1 Step -2
        result = result & Mid(hexStr, i, 2)
    Next i
    
    ReverseHexEndian = result
End Function

IEEE754解码

' 在模块顶部声明 API 函数
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
    (Destination As Any, Source As Any, ByVal Length As Long)

' 将十六进制字符串转换为 IEEE 754 单精度浮点数
Function HexToSingle(ByVal hexStr As String) As Single
    ' 检查输入长度是否为8个字符（4字节）
    If Len(hexStr) <> 8 Then
        Err.Raise 5, "HexToSingle", "输入必须是8个字符的十六进制字符串"
        Exit Function
    End If
    
    ' 将十六进制字符串转换为字节数组
    Dim byteArray(0 To 3) As Byte
    Dim i As Integer
    
    For i = 0 To 3
        ' 每两个字符转换为一个字节
        byteArray(i) = CByte("&H" & Mid(hexStr, i * 2 + 1, 2))
    Next i
    
    ' 使用 BytesToSingle 函数转换
    HexToSingle = BytesToSingle(byteArray)
End Function

' 辅助函数：将字节数组转换为 Single
Private Function BytesToSingle(byteArray() As Byte) As Single
    Dim result As Single
    CopyMemory result, byteArray(LBound(byteArray)), 4
    BytesToSingle = result
End Function

解析数据

Public Function ParseData(ByVal strData As String) As Single
    strData = Replace(strData, vbNewLine, "")
    strData = Trim(strData)
    strData = Replace(strData, " ", "")
    If Len(strData) <= 4 Then
        ParseData = -1
        Exit Function
    End If
    
    Dim strCRC As String
    Dim leftInst As String
    strCRC = Right(strData, 4)
    leftInst = Left(strData, Len(strData) - 4)
    
    Dim cCRC As String
    cCRC = GetCRCString(leftInst)
    If cCRC <> strCRC Then
        ParseData = -1
        Exit Function
    End If
    
    Dim strNumber As String
    strNumber = Right(leftInst, 8)
   ' strNumber 是接受到的响应结果中的数据段，如果按照 IEEE754 大端序解码，则直接调用 HexToSingle。
   ' 相反，如果按照小端序解码则需要先调用 ReverseHexEndian 进行反转再解码
            
    Dim strRev As String
    strRev = ReverseHexEndian(strNumber)
    ParseData = HexToSingle(strRev)
End Function
不积跬步无以至千里
Copyright © 2026 chanchaw